Just nu i M3-nätverket
Gå till innehåll
fredrik013

matcha 2 listor

Rekommendera Poster

fredrik013

Jag har 2 listor, en med adresser och en med ärenden från vårt kundregister. Det jag vill göra är att ta fram adresserna till de kunder som har ärende från adresslistan. Båda listorna innehåller personnummer.

Hur kan jag lösa detta? Jag har testat med funktionen letarad och den hittar raderna ifråga men hur kan jag sedan sortera det så jag får datan på rätt plats? Eller är det rent av någon annan funktion jag borde använda?

Dela detta inlägg


Länk till inlägg
Dela på andra webbplatser
MH_

Letarad borde funka alldeles utmärkt OM personnumret står längs till vänster i lista2

Förutsättningar för exempel:

  • Personnumret står i kolumn A i lista1
  • Lista2 finns på blad2, A1:F1000
  • Personnumret i lista2 står i kolumn A

Exempel om du vill hämta värdet i kolumn b från tabell2 (2:a kolumnen i tabell 2) när personnumret i lista 1 passar personnumret i lista2.

 

=LETARAD(A2;Blad2!$A$1:$F$1000;2;FALSKT)

eller kolumnC

=LETARAD(A2;Blad2!$A$1:$F$1000;3;FALSKT)

 

om personnumret inte står längst till vänster så kan du testa PASSA() och INDEX() (i exemplet står personnumret i a-kolumnen, men det behöver inte göra det)

Passa letar rätt på vilken rad som innehåller personnumret från cell A2

=PASSA(A2;Blad2!$A$1:$A$1000;0)

Sen använder man index för att hämta värdet i kolumn B

=INDEX(Blad2!$B$1:$B$1000;PASSA(A2;Blad2!$A$1:$A$1000;0))

och om du vill slippa felmeddelanden:

=omfel(INDEX(Blad2!$B$1:$B$1000;PASSA(A2;Blad2!$A$1:$A$1000;0));"")

 

I nyare excel så finns det en färdig funktion där PASSA/INDEX är hopbyggda

Sök personnumret (A2) i kolumn A och returnera värdet från Kolumn B:

=XLETAUPP(A2;Blad2!$A$1:$A$1000;Blad2!$B$1:$B$1000)

https://support.microsoft.com/sv-se/office/xletaupp-funktionen-xletaupp-b7fd680e-6d10-43e6-84f9-88eae8bf5929

 

Du kan till och med bestämma vad det skall stå om det inte går att hitta personnumret i tabell2

=XLETAUPP(A2;Blad2!$A$1:$A$1000;Blad2!$B$1:$B$1000;"saknas i tab2")

 

Redigerad av MH_

Dela detta inlägg


Länk till inlägg
Dela på andra webbplatser

Skapa ett konto eller logga in för att kommentera

Du måste vara medlem för att kunna kommentera

Skapa ett konto

Skapa ett nytt konto på vårt forum. Det är lätt!

Registrera ett nytt konto

Logga in

Redan medlem? Logga in här.

Logga in nu



×
×
  • Skapa nytt...