Förskjutning?

[Maczea]

Hej alla!

 

Är ny på både forumet och Excel så ber om ursäkt för min okunskap som kommer visa sig här.

Jobbar som arbetsledare på ett företag och försöker skapa mig en arbetsbok så jag lättare ska kunna hålla koll på pågående projekt.

Tanken är som följande, blad1 i boken ställer jag upp olika titlar över mindre projekt inom det större som kräver extra bevakning då det är många inblandade.

För varje mindre projekt skapas ett nytt blad, och denna kommer agera loggbok. 

 

Idealt vore om jag kan få en formel att visa i en kolumn på blad1 att hämta senaste texten i en kolumn på blad2 osv för att kunna skapa en enkel överblick på förstasidan. Lyckas inte få till denna funktion med förskjutning, är det jag som försöker med fel formel?

 

Tack på förhand!

[Ove Söderlund]

Du är på rätt spår med Förskjutning, det som du behöver är att ha med är Indirekt-referenser till fliknamn. Mitt förslag blir följande;

 

Exempel på sammanställning på Blad1

 

Och formeln i kolumn C2 blir:

=FÖRSKJUTNING(INDIREKT("'" & B2 & "'!A1");ANTALV(INDIREKT("'" & B2 & "'!A:A"))-1;0)

Bara att autofylla nedåt.

 

I Blad2 och Blad3 finns text i kolumn A.

 

Exempel-arbetsbok:

eForum 201014 Förskjutning.xlsx

 

[Maczea]

10 timmar sedan, skrev Ove Söderlund:

Du är på rätt spår med Förskjutning, det som du behöver är att ha med är Indirekt-referenser till fliknamn. Mitt förslag blir följande;

 

Exempel på sammanställning på Blad1

 

Och formeln i kolumn C2 blir:

=FÖRSKJUTNING(INDIREKT("'" & B2 & "'!A1");ANTALV(INDIREKT("'" & B2 & "'!A:A"))-1;0)

Bara att autofylla nedåt.

 

I Blad2 och Blad3 finns text i kolumn A.

 

Exempel-arbetsbok:

eForum 201014 Förskjutning.xlsx 10 kB · 1 download

 

Grymt! Stort tack! Man märker hur lite man kan om excel... Höll på att bli galen. Ska labba lite och jämföra med MH's förslag också så återkommer jag med vem som fick äran att pryda mitt dokument med formler! 

Återigen, stort tack!

/Marcus

[Maczea]

9 timmar sedan, skrev MH_:

Den enda nackdelen med Oves formel är att alla celler i kolumn A måste vara ifyllda. Det blir fel om du har någon tom rad, t.ex  om den första raden är tom.

 

I nyaste excel finns det färdiga funktioner. Lite enklare, men framför allt krävs det inte att alla rader är ifyllda:

=XLETAUPP("*";Blad2!A:A;Blad2!A:A;;2;-1)

(*=  sök efter "icke tom" cell  

;Blad2!A:A= titta i Kolumn A

;Blad2!A:A= returnera värdet i Kolumn A

;;2= värdet du söker efter är ett jokertecken

;-1)= sök från slutet av kolumnen

 

Dvs den hittar den första Icke tomma cellen räknat från slutet. Oavsett om det finns tomma rader högre upp

 

Går även att använda med förskjutning om du föredrar det: 

=FÖRSKJUTNING(Blad2!$A$1;XMATCHNING("*";Blad2!A:A;2;-1)-1;0)

 

Vill du hämta "Blad2" med formeln måste du använda @Ove Söderlund INDIREKT(),

=XLETAUPP("*";INDIREKT("'"&B2&"'!A:A");INDIREKT("'"&B2&"'!A:A");;2;-1)

Kombinerat med LET om du tycker att det blir enklare att läsa:

=LET(Omr;INDIREKT("'"&B2&"'!A:A");XLETAUPP("*";Omr;Omr;;2;-1))

 

 

 

Har du äldre Excel så kan du hitta den sista Icke-tomma raden med hjälp av:

=PRODUKTSUMMA(MAX((Blad2!A:A<>"")*RAD(Blad2!A:A)))

=Index(Blad2!A:A;PRODUKTSUMMA(MAX((Blad2!A:A<>"")*RAD(Blad2!A:A))))

=FÖRSKJUTNING(Blad2!A1;PRODUKTSUMMA(MAX((Blad2!A:A<>"")*RAD(Blad2!A:A)))-1;0)

 

Stort tack för ditt svar! Jag hade lite problem med XLETAUPP i övre delen, den envisades med att ge mig siffror när jag ändrade till kolumn E, men B kunde jag ändra till utan problem?
Finns en överhängande risk att jag slår krokben på mig själv dock.

 

Jag ska labba och knåpa vidare och försöka optimera detta dokument. 

Kommer tvinga samtliga att börja nyttja detta när jag fått ordning på layouten, knepigt när det är 40 projekt igång och det enda system är matbordet för att hålla isär status på allting. 

 

Tusen tack för att ni tog er tid att svara, ni anar inte hur mycket detta kommer underlätta mitt liv!