Just nu i M3-nätverket
Gå till innehåll
Martassen

Bokstav som representerar timmar

Rekommendera Poster

Martassen
Postad (redigerade)

Hej!

Hur gör man om man vill att A är 8 timmars pass, B ska vara 6 timmars pass och C ska vara 4 timmars pass.
Man vill ha en totalt ute till höger. När man summerar bokstäverna så ska det bli en total ute till höger.

Fått hjärnsläpp. Antar man gör en Om på detta? Ska man lägga en separat tabell där siffrorna finns och göra OM?
=OM(B4="A";8;OM(B4="B";6;4)) eller hur lägger man upp det?

Edit: Jag leker lite men osäker om det är en smidig lösning (Se även bild2). Hm ska jag istället köra Ctrl T och tabellverktyget?

Tack på förhand! 🙂

schema.jpg

bild2.jpg

Redigerad av Martassen

Dela detta inlägg


Länk till inlägg
Dela på andra webbplatser
MH_

En hjälptabell med Letarad eller liknande alltid b om du vill ha möjligheten att ändra betydelsen av bokstäverna  (om du t.ex vill ändra B till 5,5 timmar).

 

Annars finns det en massa nya OM funktioner i excel. Jag Citerar mig själv:

https://eforum.idg.se/topic/360389-excel-nyheter-och-halvnytt/

Citat

 

Ersättare för kapslade OM-formler:

IFS (flera villkor, det första sanna returneras). Ungefär som ett gäng kapslade OM fast man behöver inte hålla reda på 1000 parenteser.

Växla (Du har bara ett värde/formel etc. sen väljer man vad som skall hända beroende på vilket värde cellen/formel får) Det är ungefär som gamla Välj, men du är inte låst till 1-32 utan kan själv bestämma vilka värden du vill bevaka. Även textvärden. Exempel om du vill sätta färg på frukter:

=VÄXLA(A1;"Banan";"gul";"Äpple";"Grönt";"apelsin";"Orange";"")

 

 

I det här fallet är det väl Växla()  som blir kortare än en massa kapslade OM

=VÄXLA(B12;"A";8;"B";6;"C";4)

 

Eftersom du måste ha en modern excel för att använda VÄXLA() så kan du t.om summera direkt

=SUMMA(VÄXLA(B12:D12;"A";8;"B";6;"C";4))

Dela detta inlägg


Länk till inlägg
Dela på andra webbplatser
Martassen
Postad (redigerade)

Stort tack 🙂
Jag la in summa och växla som du föreslog. 
 

 

 

Redigerad av Martassen

Dela detta inlägg


Länk till inlägg
Dela på andra webbplatser
Martassen
Postad (redigerade)

Av nyfikenhet så tänkte jag bara hur det skulle kunna se ut om man kapslar in Om istället för summa och växla 🙂 . Hur skulle det isåfall se ut?

Testar lite: =SUMMA(OM(B12:D12="A";SUMMA(OM(B2:D12="B";6;....

 

Redigerad av Martassen

Dela detta inlägg


Länk till inlägg
Dela på andra webbplatser
MH_

Tror inte det går att nästla/kapsla på ett vettigt sätt. Det är nog enklare  att helt enkelt stapla flera Om.

 

=SUMMA(OM(B12:D12="A";8;0);OM(B12:D12="B";6;0);OM(B12:D12="C";4;0))

eller, om du kör "FALSKT" istället för 0.

=SUMMA(OM(B12:D12="A";8);OM(B12:D12="B";6);OM(B12:D12="C";4))

Obs att Varje OM skapar tre värden som summeras (0 eller talet). Det blir alltså Nio tal som summeras varav 6 av siffrorna är nollor.

 

Om du vill ha ut 3 tal som summeras så blir det någonting i stil med:

=SUMMA((B12:D12="A")*8+(B12:D12="B")*6+(B12:D12="C")*4)

=PRODUKTSUMMA((B12:D12="A")*8+(B12:D12="B")*6+(B12:D12="C")*4)

 

 

Ett alternativ är som sagt var att slå upp det i en hjälp-tabell. Så här kan du t.ex skapa de 3 siffrorna med en "hårdkodad" tabell. Det blir ganska likt koden för VÄXLA() 

=LETARAD(B12:D12;{"A",8;"B",6;"C",4};2;FALSKT)

=summa(LETARAD(B12:D12;{"A",8;"B",6;"C",4};2;FALSKT))

(OBS! Just nu har jag  excel inställt på att använda decimal-punkt istället för decimalkomma. Det är möjligt att Kommatecknet skall ersättas med något slags snedstreck i helsvens excel:  \ eller /. )

Dela detta inlägg


Länk till inlägg
Dela på andra webbplatser

Skapa ett konto eller logga in för att kommentera

Du måste vara medlem för att kunna kommentera

Skapa ett konto

Skapa ett nytt konto på vårt forum. Det är lätt!

Registrera ett nytt konto

Logga in

Redan medlem? Logga in här.

Logga in nu



×
×
  • Skapa nytt...