Index/Match med kriterier

[ante_77]

Hej,

 

Längesedan jag har varit här inne och plågat er.

Jag tycker att jag borde kunna lösa detta problem själv och har nog gjort det tidigare i mitt liv....men det bara snurrar i kupan.

 

Jag gör ett försök att förklara detta på ett bra sätt, men tvivlar på min förmåga att uttrycka mig på ett vettigt sätt.

 

Kolonnerna A, B & C består av data som är importerad.

Dokumentnummer är inte unika och således har dom olika revisioner.

 

Det jag behöver göra är att ta unika dokumentnummer (detta är ordnat) och hitta det senaste datumet (Kolumn C) som är knutet mot det dokumentnummret  och då matcha det som står i Kolumn B.

 

Hopplöst att förklara utan att peka och visa, så jag kastar in en bild och hoppas att det blir vettigt när man kombinerar text och bild.

 

Mvh Ante 

 

[Monshi]

Okej.

I G-kolumnen skriver du:

=UNIK($A$2:$A$20)

så det täcker hela din tabell (om möjligt skapa en tabell och använd tabellens namn.

I H-kolumne skriver du:

=MAXIFS($C$2:$C$20;$A$2:$A$20;G2)

som då tar fram maxdatum. Datum + DocID MÅSTE vara en unik kombination för att resultatet ska bli korrekt.

I I-kolumnen skriver du

=PRODUKTSUMMA(($A$2:$A$20=G2)*($C$2:$C$20=H2)*RAD($A$2:$A$20))

och i J-kolumnen

=INDEX($B$1:$B$20;I2)

 

Exempelvis.

Undrar om det finns knep som tar bort behovet av produktsumma i detta exempel? Matrisformler kan vara beräkningsintensiva om stora tabeller. 

Summa.omf går om man skapar en hjälpkolumn.

 

Formlerna kräver senaste version av Excel, dvs Excel 365. Det går att lösa utan dessa men blir elegantare.

 

[ante_77]

37 minuter sedan, skrev Monshi:

Okej.

I G-kolumnen skriver du:

=UNIK($A$2:$A$20)

så det täcker hela din tabell (om möjligt skapa en tabell och använd tabellens namn.

I H-kolumne skriver du:

=MAXIFS($C$2:$C$20;$A$2:$A$20;G2)

som då tar fram maxdatum. Datum + DocID MÅSTE vara en unik kombination för att resultatet ska bli korrekt.

I I-kolumnen skriver du

=PRODUKTSUMMA(($A$2:$A$20=G2)*($C$2:$C$20=H2)*RAD($A$2:$A$20))

och i J-kolumnen

=INDEX($B$1:$B$20;I2)

 

Exempelvis.

Undrar om det finns knep som tar bort behovet av produktsumma i detta exempel? Matrisformler kan vara beräkningsintensiva om stora tabeller. 

Summa.omf går om man skapar en hjälpkolumn.

 

Formlerna kräver senaste version av Excel, dvs Excel 365. Det går att lösa utan dessa men blir elegantare.

 

Jag vet inte om jag ska skratta eller gråta!!!

När jag skrev "SUMPRODUCT" formeln så undrade jag vad jag hade gjort för fel.

Jag gav mig dock på "I-kolumnen" och se på fan!!! Där kom resultatet!

 

Det tog några sekunder innan jag fattade...

 

Tusen tack!

Grymt imponerad!

[ante_77]

43 minuter sedan, skrev MH_:

Nyaste excel?

Högsta datumet i C kolumnen när dokumentnummer = G3

=MAXIFS(C:C;A:A;G3)

=MAX(OM(A:A=G3;C:C))

=XLETAUPP(G3;A:A;C:C;;0;-1)

=MAX(FILTER(C:C;A:A=G3))

eller liknande.

 

Status kan du t.ex hämta med:

=FILTER(B:B;(A:A=G3)*(C:C=H3))

 

Äldre excel

Högsta daum

. "D" formlerna (databas-formler). Anses extremt effektiva om du har mycket data.

https://support.microsoft.com/sv-se/office/dmax-funktionen-dmax-f4e8209d-8958-4c3d-a1ee-6351665d41c2

=DMAX(A:C;"Revision date";$G$3:G4)

Men på grund av hur man för in villkor data är det svårt att få det att funka som man vill med mer än en rad.

 

Produktsumma/Mängd

=PRODUKTSUMMA(MAX(($A$2:$A$100=G3)*$C$2:$C$100))

=MÄNGD(14;6;C:C/(A:A=G3);1)

 

Matrisformel

=MAX(OM(A:A=G3;C:C))

 

Status (matrisformel)

=INDEX($B$2:$B$100;PASSA(1;($A$2:$A$100=G3)*($C$2:$C$100=H3);0))

https://exceljet.net/formula/index-and-match-with-multiple-criteria

 

Jag ska göra ett försök även med dina formler, men jag tror nog att även dom kan fungera ypperligt.

Fantastiskt forum

[ChristerE]

1 timme sedan, skrev Monshi:

Formlerna kräver senaste version av Excel, dvs Excel 365.

Det som (för tillfället) är senaste versionen vid prenumeration, Microsoft 365 (tidigare Office 365) - går inte den att skaffa som engångsköp också?