Just nu i M3-nätverket
Jump to content
silverolle

ANSWERED Rensa rader som filtrerats

Recommended Posts

Jag har en tabell med ett filter där jag kan välja tex ett visst namn i listan och så ser jag alla rader det namnet finns med.

 

Jag vill exportera den listan till ett nytt blad, men vill inte ha med alla rader namnet inte finns med.

 

Tex så finns namnet på rad 4 5 7 11 24

 

Till vänster står det då de radnummer, men jag vill ha in de raderna i ett nytt blad så att de får radnummer 1 2 3 4 5

 

Är detta möjligt på ett enkelt sätt?

 

Principen jag hade tänk använda mig av är denna =Blad2.A1, men det går ju inte eftersom det blir olika rader beroende på vilket namn jag väljer.....

 

Bifogar en fil så det blir lättare att förstå....

filter.xls

Share this post


Link to post
Share on other sites

Om vi bortser från det "automatiska" så är som vanligt är pivot enklast.

 

Sen har du Avancerat filter ->till annan plats  som gör det du vill men tyvärr går det inte att göra dynamisk/automatisk. Annars hade det varit lösningen på en stor del av alla knepiga problem i det här forumet.

 

Automatiskt/länkat:

Då måste du göra en hjälpkolumn i din "databas" som kollar om raden är vald eller inte. Så vitt jag vet är den enda excelformeln som kollar om en rad är synlig DELSUMMA()

Om du låter C-kolumnen vara din hjälpkolumn så kan du använda den här formeln:

=DELSUMMA(3;A2)

 

DELSUMMA-formeln kommer att räkna hur många ifyllda namn det finns i A kolumnen. Och eftersom namnet blir osynligt för DELSUMMA när raden filtreras bort så kommer svaret vara 1 för synliga rader och 0 för bortfiltrerade.  Om man multiplicerar 0/1 med cellens radnummer så kommer den att ge svaret 0 för de rader som är borrfiltrerade och radnumret när data är framfiltrerade 

Skriv in  

=DELSUMMA(3;A2)*RAD()

i C2 och kopiera ner.

 

 

Nu blir du tvungen att använda krångliga formler, precis som i din förra fråga. 

 

I ARK 2 kan du testa den här formeln rad 1 någonstans:

=STÖRSTA(Ark1!$C$1:$C$100;RAD())

 

Om du kopierar ner formeln så ser du att den ger radnumret för de rader du är intresserad av. Tyvärr i fallande ordning. Men den siffran kan du använda för att plocka fram namn i cell A1 med hjälp av INDEX (som hämtar det N:e värdet i en lista - Vi använder STÖRSTA-formeln för att plocka fram N):

 

=INDEX(Ark1!$A$1:$A$100;STÖRSTA(Ark1!$C$1:$C$100;RAD()))

Och nummer i B1

=INDEX(Ark1!$B$1:$B$100;STÖRSTA(Ark1!$C$1:$C$100;RAD()))

(skriv in formlerna och kopiera ner)

 

Om du vill ha ha data i stigande ordning så är det lite knepigare. Då måste man använda MINSTA() för att hitta raderna vi är intresserade av och eftersom de dolda raderna är 0 så måste man hoppa över dem på något vis:

Så det här ger radnumren:

=MINSTA(Ark1!$C$1:$C$100;ANTAL.OM(Ark1!$C$1:$C$100;">0")+RAD())

 

Namnen (a1)

=INDEX(Ark1!$A$1:$A$100;MINSTA(Ark1!$C$1:$C$100;ANTAL.OM(Ark1!$C$1:$C$100;">0")+RAD()))

data (B1)

=INDEX(Ark1!$B$1:$B$100;MINSTA(Ark1!$C$1:$C$100;ANTAL.OM(Ark1!$C$1:$C$100;">0")+RAD()))

 

Och, för att slippa se felmeddelanden:

=OMFEL(INDEX(Ark1!$A$1:$A$100;MINSTA(Ark1!$C$1:$C$100;ANTAL.OM(Ark1!$C$1:$C$100;">0")+RAD()));"")

respektive

=OMFEL(INDEX(Ark1!$B$1:$B$100;MINSTA(Ark1!$C$1:$C$100;ANTAL.OM(Ark1!$C$1:$C$100;">0")+RAD()));"")

Inte vackert på något sätt....

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now



×