Macro för automatisk länkning

[Dreas]

Jag behöver hjälp med ett macro.

Jag har en jäkligt lång lista med artikelnr i exel i kloumn A.

Dessa artikelnr vill jag hyperlänka till en bestämd sökväg på datorn typ C:\artikelnr\xx.pdf.

Så makrot bör göra en sökning i kolumn A och hyperlänka det nummer som står i cellerna till motsvarande pdf-dokument i angiven sökväg.

Någon som vet hur det ska gå till?

[Monshi]

Makro? varför inte använda formeln hyperlänk?

Om fast sökväg och filnamnet värdet i cellen + pdf är ju enkelt att bygga upp.

 

=HYPERLÄNK(A1&"\"&B1 &".pdf";B1)

där sökväg i A1 och filnamn i B1.

Eller kräver du att det är cellen med filnamnet i som ska länkas?

[Mikael63]

Jag gissar att om värdet i A är E1438010 så ska länken peka till C:\Artikelnr\E1438010.pdf

[Dreas]

Ja det stämmer Monshi och Mikael. Det värde som står i A1 ska göras om/addera till en hyperlänk som går till en vald katalog på datorn.

Så om det står 2145 i A1, ska denna göras om till eller addera en hyperlänk till A1 som går till en fil som ligger på datorn som heter 2145.pdf. 

 

Alltså som Mikael säger.

 

Kan detta var något? Men jag inte köra detta på flera celler utan bara en och en.

Sub makehyper()

ActiveSheet.Hyperlinks.Add Anchor:=Selection, Address:="F:\Productdata" & Selection.Value & ".pdf" 
End Sub

[Monshi]

Sub makehyper(rn As Range, path As String)


       rn.Parent.Hyperlinks.Add Anchor:=rn, Address:=path & "\" & rn.Value & ".pdf"

End Sub



Sub MyWalker()

    Dim myRn As Range

    On Error Resume Next

    Set myRn = Application.InputBox("Markera celler att skapa länkar av", "Makehyper", Type:=8)

    On Error GoTo 0


    If myRn Is Nothing Then

        Exit Sub

    End If

    Dim myPath As Variant

    myPath = Application.InputBox("Ange den sökväg som ska användas", "Sökväg", Type:=2)

    If myPath = False Then

        Exit Sub

    End If

    Dim myStr As String

    myStr = myPath

    Dim myArea As Range

    Dim c As Range

    For Each myArea In myRn.Areas

        For Each c In myArea

            makehyper c, myStr

        Next c

    Next myArea

End Sub